Re: PL-SQL Random Number Generator?

Hi,

[Quoted] The following source code belongs to Oracle Guru, Mr.Thomas Kyte. It was not [Quoted] difficult to find since I use it.

create or replace package random
is

        pragma restrict_references( random, WNDS, RNPS );

        procedure srand( new_seed in number );

        function rand return number;
        pragma restrict_references( rand, WNDS  );

        procedure get_rand( r OUT number );

        function rand_max( n IN number ) return number;
        pragma restrict_references( rand_max, WNDS);

        procedure get_rand_max( r OUT number, n IN number );

end random;
/

create or replace package body random
is

        multiplier      constant number         := 22695477;
        increment       constant number         := 1;
        "2^32"          constant number                 := 2 ** 32;
        "2^16"          constant number         := 2 ** 16;
        "0x7fff"        constant number         := 32767;
        Seed            number := 1;
--
        procedure srand( new_seed in number )
        is
        begin
                Seed := new_seed;
        end srand;
--
        function rand return number
        is
        begin
                seed := mod( multiplier * seed + increment, "2^32" );
                return bitand( seed/"2^16", "0x7fff" );
        end rand;
--
        procedure get_rand( r OUT number )
        is
        begin
                r := rand;
        end get_rand;
--
        function rand_max( n IN number ) return number
        is
        begin
                return mod( rand, n ) + 1;
        end rand_max;
--
        procedure get_rand_max( r OUT number, n IN number )
        is
        begin
                r := rand_max( n );
        end get_rand_max;

--
begin
        select userenv( 'SESSIONID' ) into seed from dual;
end random;
/

Regards

Hakan

Jeffery Cann wrote:



> Greetings.


>

> Awhile back, a colleague of mine found an Oracle PL-SQL stored procedure

> that will generate random numbers.  Unfortunately, we cannot find the

> source and this program was not supplied from Oracle.

>

> If you have any pointers to a PL-SQL random number generator, I would

> appreciate it.

>

> Thanks.

> --

> Jeffery Cann

> Fairway Systems, Inc.

> Senior Software Engineer