SQL> declare
  2  type array_val is varray(10) of varchar2(15000);
  3  counter number:=0;
  4  SMQ_NAME ARRAY_VAL:=ARRAY_VAL();
  5  begin
  6  /* now array_val consists of these values {'a','b','c','c','a','d','c'}*/
  7  /* now i'm trying to count no of elements repeated in an arry */
  8  
  9  for I in SMQ_NAME.first .. SMQ_NAME.last
 10  LOOP
 11  a:=SMQ_NAME(I);
 12  for J in (I+1) .. SMQ_NAME.last
 13  LOOP
 14  b:=SMQ_NAME(J);
 15  
 16  if(A=B) then
 17  COUNTER:=COUNTER+1;
 18  end if;
 19  end LOOP;
 20  DBMS_OUTPUT.PUT_LINE('the value'||A||' is repeated for'||COUNTER||'times');
 21  counter:=0;
 22  end loop;
 23  
 24  end;
 25  /
a:=SMQ_NAME(I);
*
ERROR at line 11:
ORA-06550: line 11, column 1:
PLS-00363: expression 'A' cannot be used as an assignment target
ORA-06550: line 11, column 1:
PL/SQL: Statement ignored
ORA-06550: line 14, column 1:
PLS-00363: expression 'B' cannot be used as an assignment target
ORA-06550: line 14, column 1:
PL/SQL: Statement ignored
ORA-06550: line 16, column 4:
PLS-00357: Table,View Or Sequence reference 'A' not allowed in this context
ORA-06550: line 16, column 1:
PL/SQL: Statement ignored
ORA-06550: line 20, column 35:
PLS-00357: Table,View Or Sequence reference 'A' not allowed in this context
ORA-06550: line 20, column 1:
PL/SQL: Statement ignored

SQL> create or replace type array_val is varray(10) of varchar2(15);
  2  /

Type created.

SQL> declare
  2  --  type array_val is varray(10) of varchar2(15);
  3    SMQ_NAME ARRAY_VAL := ARRAY_VAL('a','b','c','c','a','d','c'); 
  4  begin
  5    for rec in (select column_value, count(*) nb from table(smq_name) 
  6                group by column_value order by column_value) 
  7    loop
  8      dbms_output.put_line('The value '||rec.column_value||' is repeated for '||rec.nb||' times');
  9    end loop;
 10  end;
 11  /
The value a is repeated for 2 times
The value b is repeated for 1 times
The value c is repeated for 3 times
The value d is repeated for 1 times

PL/SQL procedure successfully completed.

set serveroutput on
declare
    type array_val is varray(10) of varchar2(15000);
    smq_name array_val := array_val('a','b','c','c','a','d','c'); 
    type val_array is table of number
      index by varchar2(15000);
    v_arr val_array;
    v_idx varchar2(15000);
begin
    for i in 1..smq_name.count loop
      if v_arr.exists(smq_name(i))
        then
          v_arr(smq_name(i)) := v_arr(smq_name(i)) + 1;
        else
          v_arr(smq_name(i)) := 1;
      end if;
    end loop;
    v_idx := v_arr.first;
    loop
      dbms_output.put_line('Value ' || v_idx || ' is repeated '|| v_arr(v_idx) || ' times');
      v_idx := v_arr.next(v_idx);
      exit when v_idx is null;
    end loop;
end;
/
Value a is repeated 2 times
Value b is repeated 1 times
Value c is repeated 3 times
Value d is repeated 1 times

PL/SQL procedure successfully completed.

SQL>