Re: Random Number Generation in PL/SQL

On 31 Mar 1997 19:26:59 GMT, "Jeffrey P. Rudnick" <rudnijp_at_hpd.abbott.com> wrote:

>Has anyone come across a random number generation function written in
>PL/SQL?
>We are in need of random number generation over a variable domain of
>numbers.
>For example: we may need 20 random numbers between 1 and 75, and later
>30
>random numbers between 1 and 2,000. Some of the algorithms we have
>implemented from textbooks (pseudo-random number generation) go into
>repeating
>loops after a short period of time.
>
>If anyone has a PL/SQL random number algorithm they can share, we would
>greatly appreciate it.
>
>Regards,
>
>rudnijp_at_hpd.abbott.com
>

Here is one. Works the same as the C rand function.

create or replace package random
is

        pragma restrict_references( random, WNDS, RNPS );

        procedure srand( new_seed in number );

	function rand return number;
	pragma restrict_references( rand, WNDS  );

	procedure get_rand( r OUT number );

	function rand_max( n IN number ) return number;
	pragma restrict_references( rand_max, WNDS);

	procedure get_rand_max( r OUT number, n IN number );

end random;
/

create or replace package body random
is

	multiplier	constant number         := 22695477;
	increment	constant number        	:= 1;
	"2^32"		constant number			:= 2 ** 32;
	"2^16"		constant number         := 2 ** 16;
	"0x7fff"	constant number         := 32767;
	Seed		number := 1;
--
	procedure srand( new_seed in number ) 
	is
	begin
		Seed := new_seed;
	end srand;
--
	function rand return number
	is
	begin
		seed := mod( multiplier * seed + increment, "2^32" );
		return bitand( seed/"2^16", "0x7fff" );
	end rand;
--
	procedure get_rand( r OUT number ) 
	is
	begin
		r := rand;
	end get_rand;
--
	function rand_max( n IN number ) return number 
	is
	begin
		return mod( rand, n ) + 1;
	end rand_max;
--
	procedure get_rand_max( r OUT number, n IN number ) 
	is
	begin
		r := rand_max( n );
	end get_rand_max;

--
begin
	select userenv( 'SESSIONID' ) into seed from dual;
end random;
/




Thomas Kyte
tkyte_at_us.oracle.com
Oracle Government
Bethesda MD

http://govt.us.oracle.com/    -- downloadable utilities

----------------------------------------------------------------------------
Opinions are mine and do not necessarily reflect those of Oracle Corporation