Re: converting from dec to hex?

From: Joel R. Kallman <jkallman_at_us.oracle.com>
Date: 1997/06/20
Message-ID: <33aaba55.21864890_at_newshost.us.oracle.com>#1/1

Following is a message posted by Tom Kyte to this newsgroup on 05/07/1997, which answers your question

---

Not builtin, but here is a set of pl/sql routines to convert from any base
between 1 and 16 to any other base between 1 and 16...

The main routines are to_base and to to_dec. The others are just convienence
routines...

create or replace function to_base( p_dec in number, p_base in number )
return varchar2
is

        l_str   varchar2(255) default NULL;
        l_num   number  default p_dec;
        l_hex   varchar2(16) default '0123456789ABCDEF';
begin
        if ( trunc(p_dec) <> p_dec OR p_dec < 0 ) then
                raise PROGRAM_ERROR;
        end if;
        loop
                l_str := substr( l_hex, mod(l_num,p_base)+1, 1 ) ||
l_str;
                l_num := trunc( l_num/p_base );
                exit when ( l_num = 0 );
        end loop;
        return l_str;

end to_base;
/

create or replace function to_dec
( p_str in varchar2,
  p_from_base in number default 16 ) return number is

        l_num   number default 0;
        l_hex   varchar2(16) default '0123456789ABCDEF';
begin
        for i in 1 .. length(p_str) loop
                l_num := l_num * p_from_base +
instr(l_hex,upper(substr(p_str,i,1)))-1;
        end loop;
        return l_num;

end to_dec;
/
show errors

create or replace function to_hex( p_dec in number ) return varchar2 is
begin

        return to_base( p_dec, 16 );
end to_hex;
/
create or replace function to_bin( p_dec in number ) return varchar2 is
begin

        return to_base( p_dec, 2 );
end to_bin;
/
create or replace function to_oct( p_dec in number ) return varchar2 is
begin

        return to_base( p_dec, 8 );
end to_oct;
/

Thomas Kyte
tkyte_at_us.oracle.com
Oracle Government
Bethesda MD

---

On 19 Jun 1997 21:23:39 GMT, tcbracey_at_st.usm.edu (Timothy C. Bracey) wrote:

>Does anyone know how to convert from dec. to hex using PL/SQL or perhaps
>without having to write Pro C code?
>
>--
>---------------
>Timothy Corey Bracey
>Southern Station Box 4591
>University of Southern Mississippi
>Hattiesburg, MS 39406
>E-Mail: tcbracey_at_sushi.st.usm.edu
>Campus Phone: 601-266-1037

Thanks!

Joel

[Quoted] Joel R. Kallman          Enabling the Information Age through
Oracle Government                Network Computing!
Bethesda, MD                  http://govt.us.oracle.com
jkallman_at_us.oracle.com          http://www.oracle.com

---

The statements and opinions expressed here are my own and do not necessarily represent those of Oracle Corporation. Received on Fri Jun 20 1997 - 00:00:00 CEST