Re: binary format

From: Thomas Kyte <tkyte_at_us.oracle.com>
Date: Fri, 17 Apr 1998 14:26:58 GMT
Message-ID: <353965ed.7103564@192.86.155.100>

A copy of this was sent to "PC Automation" <dullery_NOSPAM_at_us.oracle.com> (if that email address didn't require changing) On 16 Apr 1998 19:41:22 GMT, you wrote:

>Anyone know how to diplay numbers in binary format?
>
>e.g. display "255" as "11111111" or "9" as "1001".

Here is a set of functions that once you install them, you can:

SQL> select to_bin( 255 ) from dual;

TO_BIN(255)

---

11111111

SQL> select to_dec( '11111111', 2 ) from dual;

TO_DEC('11111111',2)

---

                 255

SQL> select to_dec( 'ff' ) from dual;

TO_DEC('FF')

---

         255

and so on......

create or replace function to_base( p_dec in number, p_base in number ) return varchar2
is

	l_str	varchar2(255) default NULL;
	l_num	number	default p_dec;
	l_hex	varchar2(16) default '0123456789ABCDEF';
begin
	if ( trunc(p_dec) <> p_dec OR p_dec < 0 ) then
		raise PROGRAM_ERROR;
	end if;
	loop
		l_str := substr( l_hex, mod(l_num,p_base)+1, 1 ) || l_str;
		l_num := trunc( l_num/p_base );
		exit when ( l_num = 0 );
	end loop;
	return l_str;

end to_base;
/

create or replace function to_dec
( p_str in varchar2,
  p_from_base in number default 16 ) return number is

	l_num   number default 0;
	l_hex   varchar2(16) default '0123456789ABCDEF';
begin
	for i in 1 .. length(p_str) loop
		l_num := l_num * p_from_base + instr(l_hex,upper(substr(p_str,i,1)))-1;
	end loop;
	return l_num;

end to_dec;
/
show errors

create or replace function to_hex( p_dec in number ) return varchar2 is
begin

        return to_base( p_dec, 16 );
end to_hex;
/
create or replace function to_bin( p_dec in number ) return varchar2 is
begin

        return to_base( p_dec, 2 );
end to_bin;
/
create or replace function to_oct( p_dec in number ) return varchar2 is
begin

        return to_base( p_dec, 8 );
end to_oct;
/  

Thomas Kyte
tkyte_at_us.oracle.com
Oracle Government
Herndon VA  

http://govt.us.oracle.com/ -- downloadable utilities  

---

Opinions are mine and do not necessarily reflect those of Oracle Corporation  

Anti-Anti Spam Msg: if you want an answer emailed to you, you have to make it easy to get email to you. Any bounced email will be treated the same way i treat SPAM-- I delete it. Received on Fri Apr 17 1998 - 09:26:58 CDT