SQL> declare
  2    type tab is table of varchar2(100) index by varchar2(100);
  3    mytab   tab;
  4    surname varchar2(100);
  5  begin
  6    mytab('Cadot')    := 'Michel';
  7    mytab('Watson')   := 'John';
  8    mytab('Foot')     := 'Little';
  9    mytab('Swan')     := 'Black';
 10    mytab('monster')  := 'cookie';
 11    mytab('Boehmer')  := 'Barbara';
 12    mytab('division') := 'joy';
 13    surname := mytab.first;
 14    loop
 15      exit when surname is null;
 16      dbms_output.put_line(mytab(surname)||' '||surname);
 17      surname := mytab.next(surname);
 18    end loop;
 19  end;
 20  /
Barbara Boehmer
Michel Cadot
Little Foot
Black Swan
John Watson
joy division
cookie monster

PL/SQL procedure successfully completed.

declare
  type lt_type is table of varchar2(30) index by varchar2(30);
  list_tab lt_type;
  i varchar2(30);
begin
list_tab('sunny') :='salary_1';
list_tab('sunny') :='salary_2';
list_tab('test') :='salary_1';

  i := list_tab.first;
  while i is not null loop
    dbms_output.put_line( i||': '||list_tab(i) );
    i := list_tab.next(i);
  end loop;
end;
/

sunny: salary_2
test: salary_1

SQL> create or replace type list_tab1 IS object (name varchar2(20),address varchar2(20));
  2  /

Type created.

SQL> create or replace type lt_type is table of list_tab1;
  2  /

Type created.

SQL> declare
  2    list_tab lt_type;
  3  begin
  4    list_tab := lt_type(list_tab1('sunny','test_1'),
  5                        list_tab1('sunny','test_2'),
  6                        list_tab1('sunny','test_3'));
  7    FOR i IN list_tab.FIRST .. list_tab.LAST LOOP
  8      dbms_output.put_line(list_tab(i).name||' '||list_tab(i).address);
  9    end loop;
 10  end;
 11  /
sunny test_1
sunny test_2
sunny test_3

PL/SQL procedure successfully completed.

SQL> declare
  2    list_tab lt_type;
  3  begin
  4    list_tab := lt_type(list_tab1('sunny','test_1'),
  5                        list_tab1('sunny','test_2'),
  6                        list_tab1('sunny','test_3'));
  7    list_tab.delete(2);
  8    FOR i IN list_tab.FIRST .. list_tab.LAST LOOP
  9      dbms_output.put_line(list_tab(i).name||' '||list_tab(i).address);
 10    end loop;
 11  end;
 12  /
sunny test_1
declare
*
ERROR at line 1:
ORA-01403: no data found
ORA-06512: at line 9

SQL> declare
  2    list_tab lt_type;
  3    i        pls_integer;
  4  begin
  5    list_tab := lt_type(list_tab1('sunny','test_1'),
  6                        list_tab1('sunny','test_2'),
  7                        list_tab1('sunny','test_3'));
  8    list_tab.delete(2);
  9    i := list_tab.first;
 10    loop
 11      exit when i is null;
 12      dbms_output.put_line(list_tab(i).name||' '||list_tab(i).address);
 13      i := list_tab.next(i);
 14    end loop;
 15  end;
 16  /
sunny test_1
sunny test_3

PL/SQL procedure successfully completed.

DECLARE
type t_features
IS
  TABLE OF VARCHAR(100) INDEX BY pls_integer;
type t_car_rec
IS
  record
  (
    make  VARCHAR2(50),
    model VARCHAR2(50),
    features t_features );
type t_car_tab
IS
  TABLE OF t_car_rec INDEX BY pls_integer;
  car_tab t_car_tab;
PROCEDURE show_detail
IS
  car_idx pls_integer;
  features_idx pls_integer;
BEGIN
  car_idx := car_tab.first;
  LOOP
    EXIT
  WHEN car_idx IS NULL;
    dbms_output.put_line('Details for ' || car_tab(car_idx).make || ' ' || car_tab(car_idx).model);
    features_idx := car_tab(car_idx).features.first;
    LOOP
      EXIT
    WHEN features_idx IS NULL;
      dbms_output.put_line(' =>' || car_tab(car_idx).features(features_idx));
      features_idx := car_tab(car_idx).features.next(features_idx);
    END LOOP;
    car_idx := car_tab.next(car_idx);
  END LOOP;
END;
BEGIN
  -- using sequential index values
  car_tab(1).make        := 'Ferrari';
  car_tab(1).model       := 'Testarossa';
  car_tab(1).features(1) := 'Fast';
  car_tab(1).features(2) := 'Looks cool';
  car_tab(1).features(3) := 'Expensive';
  -- using random index values (sparse)
  car_tab(2).make          := 'Acura';
  car_tab(2).model         := 'TSX';
  car_tab(2).features(14)  := 'Small';
  car_tab(2).features(200) := 'Good MPG';
  car_tab(2).features(36)  := 'Inexpensive';
  show_detail;
END;

DECLARE 
    TYPE t_features 
      IS TABLE OF VARCHAR(100) INDEX BY PLS_INTEGER; 
    TYPE t_car_rec IS RECORD ( 
      make VARCHAR2(50), 
      model VARCHAR2(50), 
      features T_FEATURES ); 
    TYPE t_car_tab 
      IS TABLE OF T_CAR_REC INDEX BY PLS_INTEGER; 
    car_tab      T_CAR_TAB; 
    car_idx      PLS_INTEGER; 
    features_idx PLS_INTEGER; 
BEGIN 
    -- using sequential index values 
    Car_tab(1).make := 'Ferrari'; 

    Car_tab(1).model := 'Testarossa'; 

    Car_tab(1).Features(1) := 'Fast'; 

    Car_tab(1).Features(2) := 'Looks cool'; 

    Car_tab(1).Features(3) := 'Expensive'; 

    -- using random index values (sparse) 
    Car_tab(2).make := 'Acura'; 

    Car_tab(2).model := 'TSX'; 

    Car_tab(2).Features(14) := 'Small'; 

    Car_tab(2).Features(200) := 'Good MPG'; 

    Car_tab(2).Features(36) := 'Inexpensive'; 

    car_idx := car_tab.first; 

    LOOP 
        EXIT WHEN car_idx IS NULL; 

        dbms_output.Put_line('Details for ' 
                             || Car_tab(car_idx).make 
                             || ' ' 
                             || Car_tab(car_idx).model); 

        features_idx := Car_tab(car_idx).features.first; 

        LOOP 
            EXIT WHEN features_idx IS NULL; 

            dbms_output.Put_line(' =>' 
                                 || Car_tab(car_idx).Features(features_idx)); 

            features_idx := Car_tab(car_idx).features.NEXT(features_idx); 
        END LOOP; 

        car_idx := car_tab.NEXT(car_idx); 
    END LOOP; 
END; 
/