1. BY REFERENENCE
2. BY VALUE (the default for PL/SQL)

1. If you pass BY VALUE (the default), then a copy is made of the value you want to pass and the copy is sent to the called procedure.  But if you pass by reference then you send the memory address of where the value lives to the called procedure which means the called procedure can make changes to your original value since there is no copy of it.

2. If you pass BY VALUE then if something bad happens inside the called procedure and you fail back out to the calling procedure, the original value of your variable is untouched because the called procedure was never working on it; it was given a copy of it.  So any changes it might have made to the copy before it crapped out on you, are simply forgotten along with the copy.

3. But if you pass BY REFERENCE, you give the called procedure the memory address of your parameter's value telling the called procedure that it should manipulate the value at that location.  Thus there is no copy made.  If your called procedure makes changes to the parameter and then the called procedure fails, your calling procedure is stuck with whatever the called procedure did to your parameter value.  This can cause problems if you intend to try and continue on since the value you started with is gone forever.

create or replace procedure kev_normal (anumber_p in out integer)
as
begin
   anumber_p := anumber_p+1;
   raise zero_divide;
end;
/
show errors

create or replace procedure kev_nocopy(anumber_p in out nocopy integer)
as
begin
   anumber_p := anumber_p+1;
   raise zero_divide;
end;
/
show errors

set serveroutput on

create or replace procedure kevp1
as
   myvar integer;
begin
   myvar := 1;
   dbms_output.put_line('start myvar='||myvar);
   begin
      kev_normal (myvar);
   exception when others then
      dbms_output.put_line('normal myvar='||myvar);
   end;
--
-- my var is still 1 at this point so let us pass it using NOCOPY
--
   begin
      kev_nocopy (myvar);
   exception when others then
      dbms_output.put_line('nocopy myvar='||myvar);
   end;
end;
/
show errors

exec kevp1

23:22:57 SQL> exec kevp1
start myvar=1
normal myvar=1
nocopy myvar=2

PL/SQL procedure successfully completed.

Elapsed: 00:00:00.01