DECLARE
  l_ldap_host    VARCHAR2(256) := '10.1.151.3';
  l_ldap_port    VARCHAR2(256) := '389';
  l_ldap_user    VARCHAR2(256) := 'cn=Anonymous';
  l_ldap_passwd  VARCHAR2(256) := '';
  l_ldap_base    VARCHAR2(256) := 'o=rdkkeys';
  l_retval       PLS_INTEGER;
  l_session      dbms_ldap.SESSION;
  l_attrs        dbms_ldap.string_collection;
  l_message      dbms_ldap.message;
  l_entry        dbms_ldap.message;
  l_attr_name    VARCHAR2(256);
  l_ber_element  dbms_ldap.ber_element;
  l_vals         dbms_ldap.string_collection;
BEGIN
  -- Choose to raise exceptions.
  dbms_ldap.use_exception := true;
  
  -- Connect to the LDAP server.
  l_session := dbms_ldap.Init(hostname => l_ldap_host,portnum => l_ldap_port);
  
  l_retval := dbms_ldap.Simple_bind_s(ld => l_session,dn => l_ldap_user,passwd => l_ldap_passwd);
  
  -- Get all attributes
  L_attrs(1) := 'rdkuserid';
  
  L_attrs(2) := 'rdkexpiretime'; -- retrieve all attributes
  
  l_retval := dbms_ldap.Search_s(ld => l_session,base => l_ldap_base,scope => dbms_ldap.scope_subtree,
                                 filter => 'objectclass=*',attrs => l_attrs,
                                 attronly => 0,res => l_message);
  
  IF dbms_ldap.Count_entries(ld => l_session,msg => l_message) > 0 THEN
    -- Get all the entries returned by our search.
    l_entry := dbms_ldap.First_entry(ld => l_session,msg => l_message);
    
    <<entry_loop>>
    WHILE l_entry IS NOT NULL  LOOP
      -- Get all the attributes for this entry.
      dbms_output.Put_line('---------------------------------------');
      
      l_attr_name := dbms_ldap.First_attribute(ld => l_session,ldapentry => l_entry,ber_elem => l_ber_element);
      
      <<attributes_loop>>
      WHILE l_attr_name IS NOT NULL  LOOP
        -- Get all the values for this attribute.
        l_vals := dbms_ldap.Get_values(ld => l_session,ldapentry => l_entry,attr => l_attr_name);
        
        <<values_loop>>
        FOR i IN l_vals.FIRST.. l_vals.LAST LOOP
          dbms_output.Put_line('ATTIBUTE_NAME: '
                               ||l_attr_name
                               ||' = '
                               ||Substr(L_vals(i),1,200));
        END LOOP values_loop;
        
        l_attr_name := dbms_ldap.Next_attribute(ld => l_session,ldapentry => l_entry,ber_elem => l_ber_element);
      END LOOP attibutes_loop;
      
      l_entry := dbms_ldap.Next_entry(ld => l_session,msg => l_entry);
    END LOOP entry_loop;
  END IF;
  
  -- Disconnect from the LDAP server.
  l_retval := dbms_ldap.Unbind_s(ld => l_session);
  
  dbms_output.Put_line('L_RETVAL: '
                       ||l_retval);
END;