Home » SQL & PL/SQL » SQL & PL/SQL » bulk collect (Oracle,10g,windows xp)
bulk collect [message #415382] Mon, 27 July 2009 09:15 Go to next message
sundarfaq
Messages: 235
Registered: October 2007
Location: Chennai
Senior Member
Hi,

i have inserted million of record into one table using bulk colleck method. i have implemented by using procedure.

CREATE OR REPLACE PROCEDURE populate_pr_tx_cg_t
IS
   CURSOR cur_pr_tx_cg
   IS
      SELECT   origin, destination, va_product_code, awb_type, dow.pros_dow,
               time_window, allotment_id, TRUNC (bkg_departure_date),
               bkg_transaction_date, bkg_dcp, bkg_dcp, bkg_transaction_type,
               bkg_transaction_key, SUM (bkg_weight_count),
               SUM (bkg_volume_count), 0, TO_DATE ('27-JUL-2008')
          FROM booking_trans_raw t, day_of_week dow
         WHERE dow.dow = t.dow
           AND origin <> destination
           AND bkg_departure_date >= '02-OCT-2007'
      GROUP BY origin,
               destination,
               va_product_code,
               awb_type,
               dow.pros_dow,
               time_window,
               allotment_id,
               TRUNC (bkg_departure_date),
               bkg_transaction_date,
               bkg_dcp,
               bkg_transaction_type,
               bkg_transaction_key;

   TYPE cur_pr_tx_cg_aat IS TABLE OF cur_pr_tx_cg%ROWTYPE
      INDEX BY PLS_INTEGER;

   l_pr_tx_cg_aat   cur_pr_tx_cg_aat;
BEGIN
   OPEN cur_pr_tx_cg;

   LOOP
      FETCH cur_pr_tx_cg
      BULK COLLECT INTO l_pr_tx_cg_aat LIMIT 8000;

      FORALL i IN l_pr_tx_cg_aat.FIRST .. l_pr_tx_cg_aat.LAST
         INSERT INTO pr_tx_cg
                     (orgn,
                      dstn,
                      vap_type,
                      awb_type,
                      dow,
                      time_window,
                      allotment_id,
                      service_date,
                      transaction_date_time,
                      days_prior,
                      dcp,
                      transaction_type,
                      transaction_key,
                      weight_count,
                      volume_count,
                      counted_flag,
                      process_date
                     )
              VALUES (l_pr_tx_cg_aat (i)
                     );
      EXIT WHEN cur_pr_tx_cg%NOTFOUND;
   END LOOP;

   CLOSE cur_pr_tx_cg;
END;
/

During the compliation, the PL/SQL: ORA-00947: not enough values error shows in the l_pr_tx_cg_aat (i). how can we resolve this issues?

[EDITED by LF: applied [code] tags]

[Updated on: Tue, 28 July 2009 02:06] by Moderator

Report message to a moderator

Re: bulk collect [message #415383 is a reply to message #415382] Mon, 27 July 2009 09:17 Go to previous messageGo to next message
BlackSwan
Messages: 25036
Registered: January 2009
Location: SoCal
Senior Member
>During the compliation, the PL/SQL: ORA-00947: not enough values error shows in the l_pr_tx_cg_aat (i). how can we resolve this issues?

Provide all expected values.

You need to help us by following the Posting Guidelines as stated below.
http://www.orafaq.com/forum/t/88153/0/
Go to the URL above click the link "Posting Guidelines"
Go to the section labeled "Practice" & do as directed.
Re: bulk collect [message #415410 is a reply to message #415382] Mon, 27 July 2009 10:30 Go to previous messageGo to next message
Michel Cadot
Messages: 64103
Registered: March 2007
Location: Nanterre, France, http://...
Senior Member
Account Moderator
Still unable to format your post?

Regards
Michel
Re: bulk collect [message #415419 is a reply to message #415382] Mon, 27 July 2009 11:42 Go to previous messageGo to next message
flyboy
Messages: 1832
Registered: November 2006
Senior Member
holdingbe wrote on Mon, 27 July 2009 16:15
During the compliation, the PL/SQL: ORA-00947: not enough values error shows in the l_pr_tx_cg_aat (i). how can we resolve this issues?

What about reading Oracle documentation about the feature you are using? It is available e.g. online on http://tahiti.oracle.com/.

PL/SQL User's Guide and Reference
Chapter 5 Using PL/SQL Collections and Records
Assigning Values to Records
Inserting PL/SQL Records into the Database
SQL> create table t1( c1 integer );

Table created.

SQL> declare
  2    cursor c is
  3      select level
  4      from dual
  5      connect by level < 5;
  6    type t_c is table of c%rowtype;
  7    l_c t_c;
  8  begin
  9    open c;
 10    fetch c bulk collect into l_c;
 11    forall i in l_c.first..l_c.last
 12      insert into t1 values (l_c(i));
 13    close c;
 14  end;
 15  /
    insert into t1 values (l_c(i));
                           *
ERROR at line 12:
ORA-06550: line 12, column 28:
PLS-00382: expression is of wrong type

SQL> declare
  2    cursor c is
  3      select level
  4      from dual
  5      connect by level < 5;
  6    type t_c is table of c%rowtype;
  7    l_c t_c;
  8  begin
  9    open c;
 10    fetch c bulk collect into l_c;
 11    forall i in l_c.first..l_c.last
 12      insert into t1 values l_c(i);
 13    close c;
 14  end;
 15  /

PL/SQL procedure successfully completed.

SQL> 
SQL> select * from t1;

        C1
----------
         1
         2
         3
         4

SQL> 

Or, even better, throw it all away and use simple INSERT SELECT:
SQL> insert into t1( c1 )
  2  select level
  3  from dual
  4  connect by level < 5;

4 rows created.

SQL> 
Re: bulk collect [message #415423 is a reply to message #415382] Mon, 27 July 2009 12:49 Go to previous messageGo to next message
joy_division
Messages: 4640
Registered: February 2005
Location: East Coast USA
Senior Member
holdingbe wrote on Mon, 27 July 2009 10:15

SUM (bkg_volume_count), 0, TO_DATE ('27-JUL-2008')
.
.
.
AND bkg_departure_date >= '02-OCT-2007'



Still don't know how to use DATEs in Oracle?
Re: bulk collect [message #415442 is a reply to message #415423] Mon, 27 July 2009 21:04 Go to previous messageGo to next message
ajitpal.s
Messages: 204
Registered: November 2006
Senior Member
hi joy_division,

i was just reading this post, could you enlighten us on the issue with the dates?
Re: bulk collect [message #415443 is a reply to message #415382] Mon, 27 July 2009 21:08 Go to previous messageGo to next message
BlackSwan
Messages: 25036
Registered: January 2009
Location: SoCal
Senior Member
with Oracle, characters between single quote marks are STRINGS!
'this is a string, 2009-07-27, not a date'
what data is contained in line below?
'09-08-07'

When you desire a DATE datatype, you should use TO_DATE() function
Re: bulk collect [message #415445 is a reply to message #415443] Mon, 27 July 2009 21:45 Go to previous messageGo to next message
ajitpal.s
Messages: 204
Registered: November 2006
Senior Member
So meaning to say the following code

SUM (bkg_volume_count), 0, TO_DATE ('27-JUL-2008')
.
.
.
AND bkg_departure_date >= '02-OCT-2007'


should have being written something like below, with to_date?

SUM (bkg_volume_count), 0, TO_DATE ('27-JUL-2008', 'dd-mm-yyyy')
.
.
.
AND bkg_departure_date >= TO_DATE ('02-OCT-2007', 'dd-mm-yyyy')


But i noticed sometimes lets say you have a table with defination below
create table test_date(
  col1 date );

insert into test_date values (to_date('1-Jan-2008','dd-mm-yyyy'));
insert into test_date values (to_date('2-Jan-2008','dd-mm-yyyy'));
insert into test_date values (to_date('3-Jan-2008','dd-mm-yyyy'));
insert into test_date values (to_date('4-Jan-2008','dd-mm-yyyy'));
insert into test_date values (to_date('5-Jan-2008','dd-mm-yyyy'));


select count(*) from test_date where col1 >= '1-Jan-2008'
It still gives 5 row count, which is correct even if i use >=
'a string'

So im not sure the purpose of using to_date conversion when string also gives the right results

[Updated on: Mon, 27 July 2009 21:47]

Report message to a moderator

Re: bulk collect [message #415446 is a reply to message #415382] Mon, 27 July 2009 22:12 Go to previous messageGo to next message
BlackSwan
Messages: 25036
Registered: January 2009
Location: SoCal
Senior Member
>It still gives 5 row count, which is correct even if i use >= 'a string'

comparing string against date may give desired/correct results, wrong results, or error.

When TO_DATE is used, then correct results are assured.

Again what "date" is the following string '09-08-07'?
What is the correct answer?
Re: bulk collect [message #415448 is a reply to message #415446] Mon, 27 July 2009 22:21 Go to previous messageGo to next message
ajitpal.s
Messages: 204
Registered: November 2006
Senior Member
haha, im not sure what date is '09-08-07'. its ambiguous.

It would have made more sense if it made use of the to_date, which then specifies the format

what is the correct answer by the way Smile ?

[Updated on: Mon, 27 July 2009 22:21]

Report message to a moderator

Re: bulk collect [message #415449 is a reply to message #415382] Mon, 27 July 2009 22:29 Go to previous messageGo to next message
BlackSwan
Messages: 25036
Registered: January 2009
Location: SoCal
Senior Member
>haha, im not sure what date is '09-08-07'.
But it gives me right answer.

BEGIN
IF ( '01-APR-2009' > '01-JAN-2008' )
Then
   dbms_output.put_line('THEN');
ELSE
   dbms_output.put_line('ELSE');
END IF;
END;


What gets printed & why?
Re: bulk collect [message #415452 is a reply to message #415449] Mon, 27 July 2009 23:07 Go to previous messageGo to next message
ajitpal.s
Messages: 204
Registered: November 2006
Senior Member
oh cool example, that clarifies my doubts, thanks man
Re: bulk collect [message #415454 is a reply to message #415382] Mon, 27 July 2009 23:09 Go to previous messageGo to next message
BlackSwan
Messages: 25036
Registered: January 2009
Location: SoCal
Senior Member
What gets printed & why?
Re: bulk collect [message #415457 is a reply to message #415382] Mon, 27 July 2009 23:23 Go to previous messageGo to next message
sundarfaq
Messages: 235
Registered: October 2007
Location: Chennai
Senior Member
i have inserted millions of records from one table to other table using BULK COLLECT method and normal insert query. both of them takes same time.Here, i have posted my code.

normal insert query:
INSERT INTO PR_TX_CG_t (
   orgn, dstn,
   vap_type, awb_type, dow, time_window, allotment_id,
   service_date, transaction_date_time, days_prior, dcp,
   transaction_type,
   transaction_key,
   weight_count, volume_count, counted_flag, process_date)
(SELECT  origin, destination,
   va_product_code, awb_type, DOW.pros_dow, time_window, allotment_id,
   trunc(bkg_departure_date), bkg_transaction_date, bkg_dcp, bkg_dcp,
   bkg_transaction_type,
   bkg_transaction_key,
   sum(bkg_weight_count), sum(bkg_volume_count), 0, to_date('27-JUL-2008')
 FROM booking_trans_raw T, Day_Of_Week DOW
 WHERE
  DOW.dow = T.dow
  and origin <> destination
  and bkg_departure_date >= to_date('02-OCT-2007')
 GROUP BY origin, destination,
   va_product_code, awb_type, DOW.pros_dow, time_window, allotment_id,
   trunc(bkg_departure_date), bkg_transaction_date, bkg_dcp,
   bkg_transaction_type,
   bkg_transaction_key
  );

Elapsed: 00:00:06.35.

Procedure(BULK COLLECT):
CREATE OR REPLACE PROCEDURE populate_pr_tx_cg
IS
   CURSOR cur_pr_tx_cg
   IS
      SELECT   origin AS origin, destination, va_product_code, awb_type,
               dow.pros_dow AS dow, time_window, allotment_id,
               TRUNC (bkg_departure_date) AS service_date,
               bkg_transaction_date AS transaction_date_time,
               bkg_dcp AS days_prior, bkg_dcp AS dcp,
               bkg_transaction_type AS transaction_type,
               bkg_transaction_key AS transaction_key,
               SUM (bkg_weight_count) AS weight_count,
               SUM (bkg_volume_count) AS volume_count, 0 AS counted_flag,
               TO_DATE ('27-JUL-2008') AS process_date
          FROM booking_trans_raw t, day_of_week dow
         WHERE dow.dow = t.dow
           AND origin <> destination
           AND bkg_departure_date >= '02-OCT-2007'
      GROUP BY origin,
               destination,
               va_product_code,
               awb_type,
               dow.pros_dow,
               time_window,
               allotment_id,
               TRUNC (bkg_departure_date),
               bkg_transaction_date,
               bkg_dcp,
               bkg_transaction_type,
               bkg_transaction_key;

   TYPE t_origin IS TABLE OF pr_tx_cg.orgn%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_destination IS TABLE OF pr_tx_cg.dstn%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_va_product_code IS TABLE OF pr_tx_cg.vap_type%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_awb_type IS TABLE OF pr_tx_cg.awb_type%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_dow IS TABLE OF pr_tx_cg.dow%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_time_window IS TABLE OF pr_tx_cg.time_window%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_allotment_id IS TABLE OF pr_tx_cg.allotment_id%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_service_date IS TABLE OF pr_tx_cg.service_date%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_transaction_date_time IS TABLE OF pr_tx_cg.transaction_date_time%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_days_prior IS TABLE OF pr_tx_cg.days_prior%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_dcp IS TABLE OF pr_tx_cg.dcp%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_transaction_type IS TABLE OF pr_tx_cg.transaction_type%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_transaction_key IS TABLE OF pr_tx_cg.transaction_key%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_weight_count IS TABLE OF pr_tx_cg.weight_count%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_volume_count IS TABLE OF pr_tx_cg.volume_count%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_counted_flag IS TABLE OF pr_tx_cg.counted_flag%TYPE
      INDEX BY PLS_INTEGER;

   TYPE t_process_date IS TABLE OF pr_tx_cg.process_date%TYPE
      INDEX BY PLS_INTEGER;

   r_origin                  t_origin;
   r_destination             t_destination;
   r_va_product_code         t_va_product_code;
   r_awb_type                t_awb_type;
   r_dow                     t_dow;
   r_time_window             t_time_window;
   r_allotment_id            t_allotment_id;
   r_service_date            t_service_date;
   r_transaction_date_time   t_transaction_date_time;
   r_days_prior              t_days_prior;
   r_dcp                     t_dcp;
   r_transaction_type        t_transaction_type;
   r_transaction_key         t_transaction_key;
   r_weight_count            t_weight_count;
   r_volume_count            t_volume_count;
   r_counted_flag            t_counted_flag;
   r_process_date            t_process_date;
BEGIN
   OPEN cur_pr_tx_cg;

   LOOP
      FETCH cur_pr_tx_cg
      BULK COLLECT INTO r_origin, r_destination, r_va_product_code,
             r_awb_type, r_dow, r_time_window, r_allotment_id,
             r_service_date, r_transaction_date_time, r_days_prior, r_dcp,
             r_transaction_type, r_transaction_key, r_weight_count,
             r_volume_count, r_counted_flag, r_process_date LIMIT 1000;

      FORALL i IN r_origin.FIRST .. r_origin.LAST
         INSERT INTO pr_tx_cg_t
                     (orgn, dstn,
                      vap_type, awb_type, dow,
                      time_window, allotment_id,
                      service_date, transaction_date_time,
                      days_prior, dcp, transaction_type,
                      transaction_key, weight_count,
                      volume_count, counted_flag,
                      process_date
                     )
              VALUES (r_origin (i), r_destination (i),
                      r_va_product_code (i), r_awb_type (i), r_dow (i),
                      r_time_window (i), r_allotment_id (i),
                      r_service_date (i), r_transaction_date_time (i),
                      r_days_prior (i), r_dcp (i), r_transaction_type (i),
                      r_transaction_key (i), r_weight_count (i),
                      r_volume_count (i), r_counted_flag (i),
                      r_process_date (i)
                     );
      EXIT WHEN cur_pr_tx_cg%NOTFOUND;
   END LOOP;
   
    COMMIT;

   CLOSE cur_pr_tx_cg;
END;
/

EXEC populate_pr_tx_cg();

Elapsed: 00:00:06.12.

Please explain why bulk collect takes times?

which one is better for performance?

[EDITED by LF: applied [code] tags]

[Updated on: Tue, 28 July 2009 02:10] by Moderator

Report message to a moderator

Re: bulk collect [message #415460 is a reply to message #415457] Mon, 27 July 2009 23:48 Go to previous messageGo to next message
Michel Cadot
Messages: 64103
Registered: March 2007
Location: Nanterre, France, http://...
Senior Member
Account Moderator
This is still not formatted.

Regards
Michel
Re: bulk collect [message #415462 is a reply to message #415423] Mon, 27 July 2009 23:54 Go to previous messageGo to next message
BlackSwan
Messages: 25036
Registered: January 2009
Location: SoCal
Senior Member
joy_division wrote on Mon, 27 July 2009 10:49

Still don't know how to use DATEs in Oracle?

Re: bulk collect [message #415463 is a reply to message #415454] Mon, 27 July 2009 23:55 Go to previous messageGo to next message
ajitpal.s
Messages: 204
Registered: November 2006
Senior Member
Quote:
What gets printed & why?



'ELSE' get printed. i think the string is converted to ascii before the greater than operation is performed

Am i right?
Re: bulk collect [message #415465 is a reply to message #415382] Tue, 28 July 2009 00:03 Go to previous messageGo to next message
sundarfaq
Messages: 235
Registered: October 2007
Location: Chennai
Senior Member
the procedures is working fine. please give the suggestions why bulk collect takes same amount of time?
Re: bulk collect [message #415466 is a reply to message #415382] Tue, 28 July 2009 00:14 Go to previous messageGo to next message
BlackSwan
Messages: 25036
Registered: January 2009
Location: SoCal
Senior Member
>the procedures is working fine. please give the suggestions why bulk collect takes same amount of time?
Because it takes the same amount of time.
Do you assert BULK COLLECT is always better?


ALTER SESSION SET SQL_TRACE=TRUE;
-- invoke the problem SQL here
ALTER SESSION SET SQL_TRACE=FALSE;

now find the trace file within ./udump folder
tkprof <trace_file.trc> trace_results.txt explain=<username>/<password>

post the contents of trace_results.txt back here
Re: bulk collect [message #415467 is a reply to message #415382] Tue, 28 July 2009 00:16 Go to previous messageGo to next message
BlackSwan
Messages: 25036
Registered: January 2009
Location: SoCal
Senior Member
>i think the string is converted to ascii before the greater than operation is performed
Converted from what to ASCII?

How does ASCII impact "greater than operation"?
Re: bulk collect [message #415468 is a reply to message #415467] Tue, 28 July 2009 00:27 Go to previous messageGo to next message
ajitpal.s
Messages: 204
Registered: November 2006
Senior Member
im having an assumption it works that way, otherwise im not really sure how 1 string is being compared to another. how does it work bettween?
Re: bulk collect [message #415470 is a reply to message #415466] Tue, 28 July 2009 00:42 Go to previous messageGo to next message
sundarfaq
Messages: 235
Registered: October 2007
Location: Chennai
Senior Member
the trace file has been enclosed with it for your references.
Re: bulk collect [message #415476 is a reply to message #415445] Tue, 28 July 2009 01:04 Go to previous messageGo to next message
Frank
Messages: 7880
Registered: March 2000
Senior Member
ajitpal.s wrote on Tue, 28 July 2009 04:45
So meaning to say the following code

SUM (bkg_volume_count), 0, TO_DATE ('27-JUL-2008')
.
.
.
AND bkg_departure_date >= '02-OCT-2007'


should have being written something like below, with to_date?

SUM (bkg_volume_count), 0, TO_DATE ('27-JUL-2008', 'dd-mm-yyyy')
.
.
.
AND bkg_departure_date >= TO_DATE ('02-OCT-2007', 'dd-mm-yyyy')



Wrong!!

Don't you have a database at your local machine to test this? If not, install one immediately (XE is easy to install). It will teach you a lot.
Re: bulk collect [message #415482 is a reply to message #415476] Tue, 28 July 2009 01:29 Go to previous messageGo to next message
ajitpal.s
Messages: 204
Registered: November 2006
Senior Member
Hi Frank,

would you mind explaining why its wrong,i have db installed locally, i feel thats how it is supposed to be written if date comparison has to be done
Re: bulk collect [message #415497 is a reply to message #415482] Tue, 28 July 2009 01:52 Go to previous messageGo to next message
Frank
Messages: 7880
Registered: March 2000
Senior Member
Take a good look at the two arguments of the TO_DATE that you used.
Also check Format Models for the meaning of each part.

[Updated on: Tue, 28 July 2009 01:54]

Report message to a moderator

Re: bulk collect [message #415515 is a reply to message #415497] Tue, 28 July 2009 02:22 Go to previous messageGo to next message
ajitpal.s
Messages: 204
Registered: November 2006
Senior Member
do you mean it should have been
to_date('27-JUL-2008', 'dd-mon-yyyy')
Re: bulk collect [message #415632 is a reply to message #415515] Tue, 28 July 2009 08:06 Go to previous messageGo to next message
joy_division
Messages: 4640
Registered: February 2005
Location: East Coast USA
Senior Member
ajitpal.s wrote on Tue, 28 July 2009 03:22
do you mean it should have been
to_date('27-JUL-2008', 'dd-mon-yyyy')



bingo.

And here is just another example of what happens when you use STRINGS and DATES.
ORCL FOO>select 1 from dual where sysdate > '01-JAN-2009';
select 1 from dual where sysdate > '01-JAN-2009'
                                   *
ERROR at line 1:
ORA-01858: a non-numeric character was found where a numeric was expected


There are many many number of date formats. What may work for you, given to someone else will fail terribly.
Re: bulk collect [message #415633 is a reply to message #415476] Tue, 28 July 2009 08:10 Go to previous messageGo to next message
joy_division
Messages: 4640
Registered: February 2005
Location: East Coast USA
Senior Member
Frank wrote on Tue, 28 July 2009 02:04
ajitpal.s wrote on Tue, 28 July 2009 04:45
So meaning to say the following code

SUM (bkg_volume_count), 0, TO_DATE ('27-JUL-2008')
.
.
.
AND bkg_departure_date >= '02-OCT-2007'


should have being written something like below, with to_date?

SUM (bkg_volume_count), 0, TO_DATE ('27-JUL-2008', 'dd-mm-yyyy')
.
.
.
AND bkg_departure_date >= TO_DATE ('02-OCT-2007', 'dd-mm-yyyy')



Wrong!!

Don't you have a database at your local machine to test this? If not, install one immediately (XE is easy to install). It will teach you a lot.


Unfortunately, it seems Oracle is a little forgiving, and believe it or not, the incorrect format mask seems to work when my NLS_DATE_FORMAT is either DD-MON-RR or MM/DD/YYYY HH24:MI:SS.
ORCL FOO>alter session set nls_date_format='dd-mon-rr';

Session altered.

ORCL FOO>select TO_DATE ('27-JUL-2008', 'dd-mm-yyyy')
  2  from dual;

TO_DATE('
---------
27-jul-08

ORCL FOO>alter session set nls_date_format='mm/dd/yyyy hh24:mi:ss';

Session altered.

ORCL FOO>select TO_DATE ('27-JUL-2008', 'dd-mm-yyyy')
  2  from dual;

TO_DATE('27-JUL-200
-------------------
07/27/2008 00:00:00

Re: bulk collect [message #415637 is a reply to message #415633] Tue, 28 July 2009 08:28 Go to previous messageGo to next message
ajitpal.s
Messages: 204
Registered: November 2006
Senior Member
yea same applies to me, thanks for the example, it helps to understand things better
Re: bulk collect [message #415672 is a reply to message #415633] Tue, 28 July 2009 10:39 Go to previous message
Frank
Messages: 7880
Registered: March 2000
Senior Member
Yes, joy_division, I saw that only after I posted my first message. I don't really understand what's going on, since it cannot be some implicit datatype conversion..
Previous Topic: calculate order function (merged for the 5th time!)
Next Topic: Showing error ora-00923 from keyword not found where expected
Goto Forum:
  


Current Time: Sun Dec 04 04:33:39 CST 2016

Total time taken to generate the page: 0.06170 seconds