declare
   c utl_tcp.connection;
   n number;
   buffer varchar2(255);
   
   l_x_dat varchar2(10); 
   l_x_izn varchar2(10);
begin
   c := utl_tcp.open_connection('proxy_name', 1234);
   n := utl_tcp.write_line(c, 'GET http://www.some_site.hr/  HTTP/1.0');
   n := utl_tcp.write_line(c);

   begin
     loop
       n := utl_tcp.read_text(c, buffer, 255);

       if instr(buffer, 'NEKI miravira pond') > 0  --> narrowing the output
       then
          dbms_output.put_line(buffer);            --> it produces a screenshot posted above
          l_x_dat := substr(buffer, 176, 10);      --> a date value
          l_x_izn := substr(buffer, 208, 10);      --> an amount
       end if;          
     end loop;
     
  exception
    when utl_tcp.end_of_input then
      null;
  end;
  
  utl_tcp.close_connection(c);

end; 

SELECT extractValue(col,'/td/span/text()'),
       extractValue(col,'/td/b/text()')
FROM ( 
  SELECT NEW xmltype('<td><span>foo</span><b>bar</b></td>') col FROM dual
) tab;

drop type fonds;
drop type fond;
create or replace type fond as object (
  fond_name  varchar2(30),
  value_date varchar2(10),
  value      varchar2(20),
  currency   varchar2(8)
  )
/
create or replace type fonds is table of fond
/
set define #
create or replace function get_fond (p_fond in varchar2) 
return fonds pipelined
is
  l_page clob;

  procedure get_page 
    -- Retrieve the page from url and record it into l_page variable
  is 
    l_pieces utl_http.html_pieces;
  begin
    -- If proxy is used the following statement must be replaced by:
    -- l_pieces := utl_http.request_pieces (
    --               'http://www.hrportfolio.com/',
    --               proxy => 'user:password@proxy_url:proxy_port'
    --             );
    l_pieces := utl_http.request_pieces('http://www.hrportfolio.com/');
    dbms_lob.createtemporary (lob_loc => l_page,
                              cache   => TRUE,
                              dur     => dbms_lob.call);
    for i in 1..l_pieces.count loop
      l_page := l_page || l_pieces(i);
    end loop;
  end;

  procedure get_table 
    -- Retrieve and keep only the wanted table from l_page
  is
  begin
    -- Table is retrieved from its id, tabelaTec1, that can be anywhere
    -- in the <TABLE> tag which can can have any case.
    -- First remove all before and including the <TABLE> tag of wanted table
    -- (any character case)
    l_page := substr(l_page, 
                     regexp_instr(l_page, 
                                  '<table [^>]+ id=["]{0,1}tabelaTec1["]{0,1}[^>]+',
                                  1, 1, 1, 'i'));
    -- Reinsert the <TABLE> tag at the beginning
    l_page := '<TABLE' || l_page;
    -- Remove all after the first </TABLE> tag (no nested table inside our one)
    l_page := substr(l_page, 1, regexp_instr(l_page, '</table>', 1, 1, 1, 'i'));
  end;

  procedure normalize
    --Normalize the l_page content to be a simple "TABLE" XML page
  is
  begin
    -- Replace any contiguous space string by a single space
    l_page := regexp_replace(l_page, '[[:space:]]+', ' ');
    -- Replace "&nbsp;" string by a space (Oracle seems to not like "&nbsp;")
    l_page := replace(l_page, '&nbsp;', ' ');
    -- Remove IMG element (any character case)
    l_page := regexp_replace(l_page, '<IMG[^>]+>', '', 1, 0, 'i');
    -- Remove all attributes in tags
    l_page := regexp_replace(l_page, '[[:alpha:]]+=[^>]+', '');
    -- Remove <SUP> parts (references to footnote in page) (any character case)
    l_page := regexp_replace(l_page, '<SUP *>[[:digit:]]+</SUP *>', '', 1, 0, 'i');
    -- Remove <A> tags (any character case)
    l_page := regexp_replace(l_page, '<[/]{0,1}A *>', '', 1, 0, 'i');
    -- Remove <DIV> tags (any character case)
    l_page := regexp_replace(l_page, '<[/]{0,1}DIV *>', '', 1, 0, 'i');
    -- Put remaining tags in upper case as Oracle XML query is case sensitive
    l_page := replace(l_page, '</table>', '</TABLE>');
    l_page := replace(l_page, '<tbody>', '<TBODY>');
    l_page := replace(l_page, '</tbody>', '</TBODY>');
    l_page := regexp_replace(l_page, 'td *>', 'TD>');
    l_page := regexp_replace(l_page, 'tr *>', 'TR>');
  end;

  procedure print (p_string in clob)
    -- Display a string in lines of "line_lg" width
  is 
    line_lg constant pls_integer := 250; -- Lines of 250 characters max.
    lg      constant pls_integer := length(p_string);
    i       pls_integer := 1;
  begin
    while i <= lg loop
      dbms_output.put_line(substr(p_string, i, line_lg));
      i := i + line_lg;
    end loop;
  end;

begin
  -- Get the wanted table and normalize it at simple XML page
  get_page;
  get_table;
  normalize;
  -- Retrieve the wanted data for the matched fonds
  for rec in (
    select extractvalue(value(tr), '//TD[position()=1]') "FOND",
           extractvalue(value(tr), '//TD[position()=5]') "DATE",
           extractvalue(value(tr), '//TD[position()=6]') "VALUE",
           extractvalue(value(tr), '//TD[position()=7]') "CURRENCY"
    from ( select xmltype(l_page) val from dual ) tt,
         table(xmlsequence(extract(tt.val, '/TABLE/TBODY/TR'))) tr
    where lower(extractvalue(value(tr), '//TD[position()=1]')) like 
           '%'||lower(p_fond)||'%'
    order by 1
  ) loop
    pipe row (fond(rec.fond, rec.date, rec.value, rec.currency));
  end loop;
exception
  when no_data_needed then
    -- Nothing to do in this case
    null;
  when others then  -- for debugging only
    print ('>>> l_page content when exception occured <<<');
    print (l_page);
    print ('>>> End of l_page content <<<');
    print (' ');
    raise;
end;
/
show error
set define &

SQL> select * from table(get_fond('growth'));
FOND_NAME                      VALUE_DATE VALUE                CURRENCY
------------------------------ ---------- -------------------- --------
HI-growth                      26.07.     8,0564               €

1 row selected.

SQL> select * from table(get_fond('KD'));
FOND_NAME                      VALUE_DATE VALUE                CURRENCY
------------------------------ ---------- -------------------- --------
KD Energija                    26.07.     9,5609               kn
KD Nova Europa                 26.07.     6,4640               kn
KD Prvi izbor                  26.07.     12,0338              kn
KD Victoria                    26.07.     14,5112              kn

4 rows selected.